CB_DELETESTRING Message

Platforms

Windows 95: Supported.
Windows 98: Supported.
Windows NT: Requires Windows NT 3.1 or later.
Windows 2000: Supported.
Windows CE: Requires Windows CE 1.0 or later.

Description & Usage

Sending the CB_DELETESTRING message to a combo box removes one of the items from its drop-down box.

Return Value

If successful, the message returns the number of items remaining in the combo box's drop-down box. If an error occured, the message returns CB_ERR.

Visual Basic-Specific Issues

None.

Parameters

wParam: The zero-based index of the string to delete from the combo box's drop-down box.
lParam: Not used -- set to zero.

Constant Definitions

Const CB_DELETESTRING = &H144
Const CB_ERR = -1

Example

When the user clicks button Command1, remove the second item from combo box's Combo1 drop-down box. To run this example, place a combo box named Combo1 and a command button named Command1 on a form window.

' This code is licensed according to the terms and conditions listed here.

' Declarations and such needed for the example:
' (Copy them to the (declarations) section of a module.)
Public Declare Function SendMessage Lib "user32.dll" Alias "SendMessageA" (ByVal hWnd As Long, ByVal Msg _
	As Long, wParam As Any, lParam As Any) As Long
Public Const CB_DELETESTRING = &H144
Public Const CB_ERR = -1

' *** Place the following code inside a form window. ***

Private Sub Command1_Click()
	Dim result As Long  ' result of string deletion attempt
	
	' Remove the second item from Combo1's drop-down list
	' box, and display the result.
	result = SendMessage(Combo1.hWnd, CB_DELETESTRING, ByVal CLng(1), ByVal CLng(0))
	If result = CB_ERR Then
		Debug.Print "Unable to delete the second string in Combo1's drop-down box."
	Else
		Debug.Print "There are"; result; "strings left in Combo1's drop-down box."
	End If
End Sub