RegSetValueEx Function

Declare Function RegSetValueEx Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpData As Any, ByVal cbData As Long) As Long

Platforms

Windows 95: Supported.
Windows 98: Supported.
Windows NT: Requires Windows NT 3.1 or later.
Windows 2000: Supported.
Windows CE: Requires Windows CE 1.0 or later.

Description & Usage

RegSetValueEx writes a value to a registry key. If the value does not already exist, it will be created. The value can be of any of the registry data types.

Return Value

If an error occured, the function returns a non-zero error code. If successful, the function returns 0.

Visual Basic-Specific Issues

When writing a string or a single numeric value, the lpData parameter must be prefixed by the ByVal keyword. Any other values (such as byte arrays) do not need the ByVal keyword.

Parameters

hKey

A handle to the registry key to write the value under. This could also be one of the following flags identifying one of the predefined registry base keys:

HKEY_CLASSES_ROOT: The HKEY_CLASSES_ROOT base key.
HKEY_CURRENT_CONFIG: The HKEY_CURRENT_CONFIG base key.
HKEY_CURRENT_USER: The HKEY_CURRENT_USER base key.
HKEY_DYN_DATA: Windows 95, 98: The HKEY_DYN_DATA base key.
HKEY_LOCAL_MACHINE: The HKEY_LOCAL_MACHINE base key.
HKEY_PERFORMANCE_DATA: Windows NT, 2000: The HKEY_PERFORMANCE_DATA base key.
HKEY_USERS: The HKEY_USERS base key.

lpValueName

The name of the value to set. If this is an empty string, the function writes to the unnamed default value (Windows 95: the default value always has the REG_SZ data type).

Reserved

Reserved. Set to 0.

dwType

One of the following flags identifying the data type of the data to write to the registry:

REG_BINARY: A non-text sequence of bytes.
REG_DWORD: Same as REG_DWORD_LITTLE_ENDIAN.
REG_DWORD_BIG_ENDIAN: A 32-bit integer stored in big-endian format. This is the opposite of the way Intel-based computers normally store numbers -- the word order is reversed.
REG_DWORD_LITTLE_ENDIAN: A 32-bit integer stored in little-endian format. This is the way Intel-based computers normally store numbers.
REG_EXPAND_SZ: A null-terminated string which contains unexpanded environment variables.
REG_LINK: A Unicode symbolic link.
REG_MULTI_SZ: A series of strings, each separated by a null character and the entire set terminated by a two null characters.
REG_NONE: No data type.
REG_RESOURCE_LIST: A list of resources in the resource map.
REG_SZ: A string terminated by a null character.

lpData

The number, string, or other data to write to the registry.

cbData

The size in bytes of the data being written to the registry.

Constant Definitions

Const HKEY_CLASSES_ROOT = &H80000000
Const HKEY_CURRENT_CONFIG = &H80000005
Const HKEY_CURRENT_USER = &H80000001
Const HKEY_DYN_DATA = &H80000006
Const HKEY_LOCAL_MACHINE = &H80000002
Const HKEY_PERFORMANCE_DATA = &H80000004
Const HKEY_USERS = &H80000003
Const REG_BINARY = 3
Const REG_DWORD = 4
Const REG_DWORD_BIG_ENDIAN = 5
Const REG_DWORD_LITTLE_ENDIAN = 4
Const REG_EXPAND_SZ = 2
Const REG_LINK = 6
Const REG_MULTI_SZ = 7
Const REG_NONE = 0
Const REG_RESOURCE_LIST = 8
Const REG_SZ = 1

Example

' This code is licensed according to the terms and conditions listed here.

' Create a key called HKEY_CURRENT_USER\Software\MyCorp\MyProgram\Config.
' Then create a "username" value under that key and set its value to "Rimmer".
Dim hregkey As Long  ' receives handle to the newly created or opened registry key
Dim secattr As SECURITY_ATTRIBUTES  ' security settings of the key
Dim subkey As String  ' name of the subkey to create
Dim neworused As Long  ' receives 1 if new key was created or 2 if an existing key was opened
Dim stringbuffer As String  ' the string to put into the registry
Dim retval As Long  ' return value

' Set the name of the new key and the default security settings
subkey = "Software\MyCorp\MyProgram\Config"
secattr.nLength = Len(secattr)  ' size of the structure
secattr.lpSecurityDescriptor = 0  ' default security level
secattr.bInheritHandle = True  ' the default value for this setting

' Create or open the registry key
retval = RegCreateKeyEx(HKEY_CURRENT_USER, subkey, 0, "", 0, KEY_WRITE, secattr, hregkey, neworused)
If retval <> 0 Then  ' error during open
  Debug.Print "Error opening or creating registry key -- aborting."
  End  ' terminate the program
End If

' Write the string to the registry.  Note that because Visual Basic is being used, the string
' passed to the function must explicitly be passed ByVal.
stringbuffer = "Rimmer" & vbNullChar  ' note how a null character must be appended to the string
retval = RegSetValueEx(hregkey, "username", 0, REG_SZ, ByVal stringbuffer, Len(stringbuffer))  ' write the string

' Close the registry key
retval = RegCloseKey(hregkey)